www.BASIC-REFERENZ.de

FIBERI - IMPRESSUM - DATENSCHUTZ - ONLINE-STREITBEILEGUNG - LINKS & HAFTUNG - SITEMAP

Seite
Menü
Info
Sie sind hier:   Startseite > MINI-KURSE > ANFÄNGER > Radioaktiver Zerfall
FIBERI - BASIC-REFERENZ 2020

Radioaktiver Zerfall

 

Eine weitere einfache graphische Darstellung ohne echte Graphik:

siehe auch:
Koordinaten-System

 

Hier wird "mal eben" der Zerfall eines radioaktiven Stoffes dargestellt, nach der Formel:

Ct = C0-kt

Wir müssen hier aber nicht in die Strahlenphysik abschweifen, es geht hier mehr darum wie einfach es ist mit ein paar Programm-Zeilen eine schnelle Verbildlichung zu geben und das ohne eine echte Graphik, da hier auch wieder nur Textzeichen verwendet werden.

 10 CLS:KEY OFF'*** KOSMETIK
 20 COLOR 10'*** FARBE GRÜN
 30 PRINT TAB(6);"0%";TAB(30);"<<<";TAB(55);"100%"'*** SKALA Y-ACHSE
 40 COLOR 7'*** FARBE DUNKEL WEISS/HELL GRAU
 50 PRINT TAB(2);"[t]";'*** EINHEITENANGABE X-ACHSE
 60 PRINT TAB(6);CHR$(218);'*** RAHMEN-ECKE
 70 FOR LINIE = 1 TO 52'*** RAHMENLINIE Y-ACHSE
 80 PRINT CHR$(196);'   *** RAHMENLINIE Y-ACHSE
 90 NEXT LINIE'         *** RAHMENLINIE Y-ACHSE
100 FOR T = 0 TO 20'*** DARSTELLUNG VERTIKALE ZEILEN
110 WERT=INT(50*EXP(-.1733*T))'*** MATHEMATISCHE FORMEL
120 COLOR 12'*** FARBE ORANGE
130 PRINT TAB(2);T;'*** SKALA X-ACHE ("[t]")
140 COLOR 7'*** FARBE DUNKEL WEISS/HELL GRAU
150 PRINT TAB(6);CHR$(179);'*** RAHMENLINIE X-ACHSE
160 COLOR 14'*** FARBE GELB
170 PRINT TAB(WERT+6);CHR$(249)'*** KURVEN-DARSTELLUNG (PUNKTE)
180 NEXT T'*** DARSTELLUNG ZEILE 1 BIS 20 ZUENDE
190 REM
200 REM *** NACHTRÄGLICHE BESCHRIFTUNG MIT LOCATE ***
210 REM
220 LOCATE 22,31'*** SPRUNGZIEL FESTLEGUNG
230 COLOR 15,1'*** SCHRIFT: WEISS / HINTERGRUND: BLAU
240 PRINT " RADIOAKTIVE ZERFALLS-KURVE "
250 LOCATE 23,31'*** SPRUNGZIEL FESTLEGUNG
260 COLOR 14,0'*** SCHRIFT: GELB / HINTERGRUND: SCHWARZ
270 PRINT "FORMEL: Ct(%) = C0*EXP(-k*t)"
280 IF INKEY$="" THEN 280'*** WARTESCHLEIFE
290 CLS:COLOR 15,0,0:LIST'*** ZUM PROGRAMMCODE

 

Würden wir hier alle Befehle nicht so ausführlich kommentieren, sondern enger zusammenschreiben, dann wären es tatsächlich nur ganz wenige Zeilen ...

... das könnte dann immer noch recht geordnet auch so aussehen:

 10 CLS:KEY OFF
 20 COLOR 10:PRINT TAB(6);"0%";TAB(30);"<<<";TAB(55);"100%"
 30 COLOR 7:PRINT TAB(2);"[t]";:PRINT TAB(6);CHR$(218);
 40 FOR LINIE = 1 TO 52:PRINT CHR$(196);:NEXT LINIE
 50 FOR T = 0 TO 20:WERT=INT(50*EXP(-.1733*T))
 60 COLOR 12:PRINT TAB(2);T;:COLOR 7:PRINT TAB(6);CHR$(179);
 70 COLOR 14:PRINT TAB(WERT+6);CHR$(249):NEXT T
 80 LOCATE 22,31:COLOR 15,1:PRINT " RADIOAKTIVE ZERFALLS-KURVE "
 90 LOCATE 23,31:COLOR 14,0:PRINT "FORMEL: Ct(%) = C0*EXP(-k*t)"
100 IF INKEY$<>"" THEN CLS:COLOR 15,0,0:LIST ELSE 100

Es ginge aber auch noch gestraffter ...!

 

Das Programm setzt 20 Werte in die zentrale mathematische Formel ein (oben: 110 WERT=INT(50*EXP(-.1733*T))) und gibt die Ergebnisse als Punkte aus. Diese sind als reine Text-Zeichen (CHR$(249)) einfach mit dem PRINT TAB-Befehl entsprechend der Höhe Ihres mathematischen Wertes vom linken Rand entfernt dargestellt (oben: 170 PRINT TAB(WERT+6);CHR$(249)). Optisch kommt dann noch ein wenig Farbe, ein Halbrahmen und die Beschriftung dazu.

Man muss sich einfach wörtlich vor Augen führen, daß ein BASIC-Interpreter-Programm (so wie hier beim PC-BASIC) Bildschirm-Zeile für Bildschirm-Zeile abarbeitet, immer von oben nach unten und links nach rechts. Nur am Ende springen wir wieder aktiv zurück hinein mit dem LOCATE-Befehl, obwohl es auch ohne geht ...

... das sieht dann so aus:

 10 CLS:KEY OFF
 20 COLOR 10:PRINT TAB(6);"0%";TAB(30);"<<<";TAB(55);"100%"
 30 COLOR 7:PRINT TAB(2);"[t]";:PRINT TAB(6);CHR$(218);
 40 FOR LINIE = 1 TO 52:PRINT CHR$(196);:NEXT LINIE
 50 FOR T = 0 TO 20:WERT=INT(50*EXP(-.1733*T))
 60 COLOR 12:PRINT TAB(2);T;:COLOR 7:PRINT TAB(6);CHR$(179);
 70 COLOR 14:PRINT TAB(WERT+6);CHR$(249);
 80 IF T = 19 THEN PRINT"                       ";:COLOR 15,1:PRINT "RADIOAKTIVE ZERFALLS-KURVE ":COLOR 14,0
 90 IF T = 20 THEN PRINT"                       ";:PRINT "FORMEL: Ct(%) = C0*EXP(-k*t)"
100 NEXT T
110 IF INKEY$<>"" THEN CLS:COLOR 15,0,0:LIST ELSE 110

Es wird hier innerhalb der  Wiederholungsschleife in den Programm-Zeilen 80 und 90 für T (FOR T = 0 TO 20) jeweils eine Abfrage (IF...THEN) gesetzt, ob schon die Werte 19 und 20 erreicht sind, also die letzte und vorletzte Bildschirm-Zeile, falls ja, dann wird mit vorangestellten Formatierungs-Leerzeichen (PRINT"  ") die entsprechende Beschriftung für den Graphen innerhalb der Bildschirm-Zeilen 22 und 23 mit ausgegeben.

 

Am Ende doch noch ein wenig Strahlenphysik!
(Soweit wir bescheiden versuchen sie nachzuvollziehen ... undecided)
 
Die BASIC-Formel, welche hier zugrundeliegt ist:

INT(50*EXP(-.1733*T))

INT() bewirkt, daß am Ende eine ganze Zahl herauskommt, die mathematische Formel selber ist:

Ct = 50-0,1733t

und soll eigentlich I124 mit der Konstante k = 0,1733 pro Tag behandeln. Als Ausgangs-Strahlungswert für C0 gehen wir von 50 µCurie aus (als Einheit der Hoch-Zeit des klassischen BASICs angmessen). Aktueller muss es natürlich in Becquerel (3,7X1010s-1) sein (= 1.85 TBq) mit einer spez. Zerfallskonstante von 1.921X10-6 s-1! Aber das wäre von der Auflösung her nicht mehr so einfach umsetzbar, konsequent müssten wir auch nach der Formel des "Zerfallsgesetzes" vorgehen:

N=N0⋅2−t/T

... hier sähe die Kurve aber dann prinzipiell auch wieder gleich aus!

Da es uns hier auch nur um eine schematische Darstellung, bzw. ihre einfache programmiertechnische Umsetzung geht, sind die Zahlen selber auch nicht interessant!

Die Formel und Konstante haben wir Spain (1982) entnommen, den Rest aber selber gemacht ... im Gegensatz zu dem, was er dort "verformuliert" hat! laughing

 


Alle nicht-pflichtigen Inhalte dieser Internet-Präsenz sind unverbindlich und ohne Gewähr! (weitere INFO!)



Seite
Menü
Info

SCHNELLEINSTIEG

So einfach geht´s zum

BASIC

"Hallo Welt !"

10 CLS
20 PRINT "Hallo Welt!"
30 GOTO 20
RUN
[Strg] + C

SICHERHEIT!

Safety First!
Deshalb: LESEN!

Seite
Menü
Info

Powered & Basis-Template by CMSimple - pimped by FIBERI
FIBERI - Fisch(erei) Beratung Ritter 2003 - 2020